Encrypting/Decrypting your PDF file using Web APIs

var
  StarDocs: TgtStarDocsSDK;
  FileObjectInput: TgtFileObject;
  DocObjectOutput: TgtDocObject;
  OldPassword: string;
  EncryptionLevel: TgtPDFEncryptionLevel;
  NewOpenPassword: string;
  NewPermissionsPassword: string;
  NewPermissions: TgtPDFDocPermissions;
begin
  StarDocs := nil;
  FileObjectInput := nil;
  DocObjectOutput := nil;
  try
    // Set up connection details
    StarDocs := TgtStarDocsSDK.Create(nil);
    StarDocs.ConnectionSettings.ApiServerUri :=
      'http://api.gnostice.com/stardocs/v1';
    StarDocs.ConnectionSettings.ApiKey := '<API Key>';
    StarDocs.ConnectionSettings.ApiSecret := '<API Secret>';
    // Force full permissions on PDF files protected 
    // with an permissions/owner/master password
    StarDocs.Preferences.DocPasswordSettings.ForceFullPermission := True;

    // Authenticate
    StarDocs.Auth.loginApp;

    // Input file
    FileObjectInput := TgtFileObject.Create('C:\Documents\Statement.pdf');

    // The existing open-password present on the document (if any)
    OldPassword := 'oldpassword';

    // The encryption level (if encrypting, else set to pelNone)
    // Supported values are pelAES_128bit(default), pelRC4_128bit 
    // and pelRC4_40bit
    EncryptionLevel := TgtPDFEncryptionLevel.pelAES_128bit;

    // The new open-password (if encrypting)
    // Pass an empty string if you want to remove the protection
    NewOpenPassword := 'newpassword';

    // The new permissions-password (if encrypting)
    // Pass an empty string if you want to remove the protection
    NewPermissionsPassword := 'newpermissionspassword';

    // Specify the restrictions to be placed on the document
    // Valid only if a non-empty NewPermissionsPassword is supplied
    NewPermissions := [
      // Specify if allow accessibility
      pdpAllowAccessibility,
      // Specify if allow document assembly
      pdpAllowAssembly,
      // True if allow content copying
      pdpAllowCopy,
      // Specify if allow form filling
      pdpAllowFormFill,
      // Specify if allow high resolution printing
      pdpAllowHighResPrint,
      // Specify if allow modifying annotations
      pdpAllowModifyAnnotations,
      // Specify if allow content modification
      pdpAllowModifyContents,
      // Specify if allow printing
      pdpAllowPrinting
    ];

    // Encrypt or decrypt the file
    DocObjectOutput := StarDocs.DocOperations.Encrypt(
      FileObjectInput,
      OldPassword,
      EncryptionLevel,
      NewOpenPassword,
      NewPermissionsPassword,
      NewPermissions);

    // Do something with resultant document (DocObjectOutput)
    // ...

  finally
    // Free objects
    if Assigned(DocObjectOutput) then
      FreeAndNil(DocObjectOutput);
    if Assigned(FileObjectInput) then
      FreeAndNil(FileObjectInput);
    if Assigned(StarDocs) then
      FreeAndNil(StarDocs);
  end;
end;