eDocEngine VCL
Create documents and reports in 18 formats

Compatibility

Delphi C++Builder

Home » Newsletter » July 2010

By V. Subhash

In the new version of eDocEngine, the PDF engine provides full support for Unicode. This means that eDocEngine can:

1. Render text in any language that has codepoints in Unicode.
2. Specify bidirectional text modes (BiDi modes) specified in Classes.TBidiMode.
3. Render text that are written from right to left such as those in Arabic, Farsi or Hebrew.
4. Automatically perform font mapping.
5. Reduce file size of document by performing subset embedding of PDF fonts in a more compact manner.

In eDocEngine v2.x, the PDF engine class TgtPDFEngine had a boolean property Bidi. In Version 3, this property is replaced with another property BiDiMode. You can use a Classes.TBidiMode enum value to set the value of this property.

Following is some sample code that illustrates Unicode capabilities of the PDF engine. In this code snippet, text in several non-English languages are rendered on a page under different bidirectional text modes. The default page font is set to Arial. However, to render text whose glyphs are not present in Arial, the PDF engine automatically finds a more suitable font. All of these fonts are set to be subset embedded in the code. Arial has been excluded from getting embedded, simply to demonstrate that it is possible to exclude certain fonts in that way.

program Demo_eDocEngine_Unicode_Demo;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes, Graphics, TypInfo,
  gtCstPDFEng, gtCstDocEng, gtPDFEng;

var
  gtPDFEngine1: TgtPDFEngine;
  ArabicStr, BrazilianPortugueseStr, ChineseStr, DeutschStr, EspañolStr,
      FrenchStr, HebrewStr, JapaneseStr, MalayalamStr,
      SanskritStr, RussianStr, TamilStr, ThaiStr: WideString;
  y: Double;
  BidiModeIterator: TBidiMode;
begin

  ArabicStr :=
    'من الحبة تنشأ الشجرة';
  BrazilianPortugueseStr :=
    'Toda regra tem uma exceção';
  ChineseStr :=
    '人要脸树要皮';
  DeutschStr :=
    'Das Eisen schmieden, solange es heiß ist';
  EspañolStr :=
    'Más vale maña que fuerza';
  FrenchStr :=
    'L''on est bien faible quand on est amoureux';
  HebrewStr :=
    'אל תסתכל בקנקן, אלא במה שבתוכו';
  JapaneseStr  :=
    'たげいはむげい';
  MalayalamStr  :=
    'പിത്തള മിനുക്കിയാല്‍ പൊന്നാവില്';
  RussianStr  :=
    'Два медве́дя в одно́й берло́ге не живу́т';
  SanskritStr :=
    'धर्मो रक्षति रक्षितः';
  TamilStr  :=
    'அறம் செய விரும்பு';
  ThaiStr  :=
    'แมลงเม่าบินเข้ากองไฟ';

  gtPDFEngine1 := TgtPDFEngine.Create(nil);

  try
    with gtPDFEngine1 do begin
      Font.Name := 'Arial';
      Font.Size := 13;
      Page.PaperSize := A3;
      Preferences.ShowSetupDialog := False;
      Preferences.OpenAfterCreate := True;
      Preferences.EmbedTrueTypeFonts := etfSubset;
      FontEmbedExcludeList.Add('Arial'); // Do not embed Arial
      Filename := 'edocengine_v3_Unicode_Demo.pdf';

      BeginDoc;

      y := 0.2;
      // Write text in multiple BiDi modes
      for BidiModeIterator  := Low(TBidiMode) to High(TBidiMode) do begin
        BiDiMode := BidiModeIterator;
        Textout(4, y, 'BiDimode is ' +
                      GetEnumName(TypeInfo(TBiDiMode), Ord(BidiModeIterator)));

        // Render text in different languages
        TextOut(4, y + 0.2,  ArabicStr);
        TextOut(4, y + 0.45, BrazilianPortugueseStr);
        TextOut(4, y + 0.7,  ChineseStr);
        TextOut(4, y + 0.95, DeutschStr);
        TextOut(4, y + 1.2,  EspañolStr);
        TextOut(4, y + 1.45, FrenchStr);
        TextOut(4, y + 1.7,  HebrewStr);
        TextOut(4, y + 1.95, JapaneseStr);
        TextOut(4, y + 2.2,  MalayalamStr);
        TextOut(4, y + 2.45, RussianStr);
        TextOut(4, y + 2.7,  SanskritStr);
        TextOut(4, y + 2.95, TamilStr);
        TextOut(4, y + 3.2,  ThaiStr);
        TextOut(4, y + 3.45, ArabicStr +  // Mixed-language string
                            ' From the seed, grows the tree ');
        y := y + 3.45 + 0.6;
      end;

      EndDoc;
    end;
  except
    on E: Exception do begin
      Writeln('Sorry, an error occured in ' +
              E.ClassName, ' with message ', E.Message);
    end;
  end;

  Writeln('Press Enter to quit');
  Readln;
end.

And, here is the output in screenshots.

Finally, examine the fonts used in the document.

Thanks to the automatic and intelligent font mapping, you do not have to specify Arial Unicode MS or some other big polyglot Unicode font to support multiple languages. eDocEngine Version 3 does all that internally. You only need to have the appropriate fonts installed in Windows.

Please note that the above code snippet requires the PAS file to be Unicode-encoded. You will be able to use it in Delphi 2007, 2009 or 2010. If you are using an older version of Delphi, then you could read the Unicode strings from a stream and store them in a TWideStringList. Alternatively, you could load them off TNT Delphi Unicode Components.

---o0O0o---

The test phrases and the meanings are listed below.

• Arabic - From the seed grows the tree - من الحبة تنشأ الشجرة
• Brazilian Portuguese - Every rule has an exception. - Toda regra tem uma exceção
• Chinese - A person needs a face like a tree needs a bark. - 人要脸树要皮
• German (Deutsch) - Strike the iron while it's hot - Das Eisen schmieden, solange es heiß ist
• French - (Madame de La Fayette) One is very weak when one is in love. - L'on est bien faible quand on est amoureux.
• Hebrew - Don't look at the jar, but at what's inside it. - אל תסתכל בקנקן, אלא במה שבתוכו
• Japanese (Nihongo) - Too many accomplishements make no accomplishments. -たげいはむげい
• Malayalam (Indian) - Brass will not become gold if you polish it. - പിത്തള മിനുക്കിയാല്‍ പൊന്നാവില്ല
• Russian - Two bears don't live in one lair. - Два медве́дя в одно́й берло́ге не живу́т.
• Sanskrit (Indian) - (Subhashita) Dharma protects those who protect it - धर्मो रक्षति रक्षितः
• Spanish (Español) - Skill is better than strength - Más vale maña que fuerza
• Tamil (Indian) - Desire doing good. - அறம் செய விரும்பு
• Thai - Flying termites fly into the fire. - แมลงเม่าบินเข้ากองไฟ